この 画像はPOV-Rayで作成されました。

この作品の著作権者である私は、この作品についての権利を放棄しパブリックドメインとします。これは全世界で適用されます。 一部の国では、これが法的に可能ではない場合があります。その場合は、次のように宣言します。 私は、あらゆる人に対して、法により必要とされている条件を除き、如何なる条件も課すことなく、あらゆる目的のためにこの著作物を使用する権利を与えます。

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing.

#include "colors.inc"

background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -25>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5
  }

light_source
  {
  <0, 20, -50>
  color White
  area_light <5, 0, 0>, <0, 5, 0>, 10, 10
  adaptive 3
  }  
  
#declare r_tube = 0.1;
#declare num_steps = 72;
#declare step_size = 1/num_steps;
              
sphere_sweep
  {
  cubic_spline 27,
  #declare N = 8;
  #while(N <= 34)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.75,0> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }

sphere_sweep
  {
  cubic_spline 27,
  #declare N = 32;
  #while(N <= 58)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <1,0,0> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }

sphere_sweep
  {
  cubic_spline 27,
  #declare N = 56;
  #while(N <= 82)
    #declare theta = 2 * pi * N * step_size;
    <0.3*( 2*sin(2*theta)-sin(theta) ), 0.3*( 2*cos(2*theta)+cos(theta) ), 0.3*sin(3*theta)>, r_tube
    /* uses a hypotrochoid */
    #declare N = N + 1;
  #end
  pigment { color rgb <0,0.25,1> }
  finish          
    {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 5
    }
  }
  

plane
  {
  <0,0,-1>, -0.4
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }